...
sub pause temp   'pause en millisecondes
    timer temp, [temps]
    wait
    [temps]
    timer 0
end sub
....
 

nomainwin
 
    WindowWidth = 880
    WindowHeight = 538
    UpperLeftX=int((DisplayWidth-WindowWidth)/2)
    UpperLeftY=int((DisplayHeight-WindowHeight)/2)
 
    Global ncx, ncy, lc, SpriteCourant
 
    lc = 15    'dimension d'une case en pixels

    open "Le Donjon De Sheidra Map N°1" for graphics_nsb_nf as #3b
    #3b "trapclose Quit"
    #3b "font Comic_Sans_MS 8"
    #3b "home; posxy CenterX CenterY"
    Gwidth = CenterX * 2
    Gheight = CenterY * 2
    ncx = int(Gwidth/lc)   'nbre de case en x
    ncy = int(Gheight/lc)   'nbre de case en y
    dim cas(ncx,ncy)  'variable tableau de toutes les limites de la map.

    loadbmp "JB", "bmp\maphum2.bmp"
    sprites$ = "perso1d perso2d perso3d perso4d perso1s perso2s perso3s perso4s "+_
               "perso1q perso2q perso3q perso4q perso1z perso2z perso3z perso4z"
    for s = 1 to 16
        loadbmp word$(sprites$,s), "bmp\"+word$(sprites$,s)+".bmp"
    next
    #3b "addsprite perso1 perso1z perso2z perso3z perso4z"  'création des 4 sprites pour chaque futures direction de déplacement...
    #3b "addsprite perso2 perso1d perso2d perso3d perso4d"
    #3b "addsprite perso3 perso1s perso2s perso3s perso4s"
    #3b "addsprite perso4 perso1q perso2q perso3q perso4q"
 
    #3b "down"
    #3b "drawbmp JB 0 0"
    #3b "color darkgray"
    for x = 1 to ncx
        #3b "place ";x*lc;" 0"
        #3b "goto ";x*lc;" ";ncy*lc  'traits verticaux de la grille
    next
    for y = 1 to ncy
        #3b "place 0 ";y*lc
        #3b "goto ";ncx*lc;" ";y*lc  'traits horizontaux de la grille
    next
 
    #3b "getbmp bckgrd1 0 0 ";Gwidth;" ";Gheight   'mémorise la grille pour servir de background au sprite "curs"
    #3b "background bckgrd1"
 
    for SpriteCourant = 1 to 4
        #3b "spritexy perso";SpriteCourant;" ";12*lc;" ";24*lc   'place tous les sprites là.
        #3b "cyclesprite perso";SpriteCourant;" 1"
        #3b "spritevisible perso";SpriteCourant;" off"
    next
    SpriteCourant = 3
    #3b "spritevisible perso";SpriteCourant;" on"
    #3b "drawsprites"                      'affiche le sprite courant.

    #3b "when leftButtonMove SimpleClick"    'pour tracer et enregistrer les limites.
    #3b "when leftButtonDouble DoubleClick"    'pour déplacer le personnage...

wait
 
sub SimpleClick handle$, MouseX, MouseY
    mx = int(MouseX / lc)+1
    my = int(MouseY / lc)+1
    #3b "spritevisible perso";SpriteCourant;" off; drawsprites"
    if mx>0 and mx<ncx and my>0 and my<ncy then
        cas(mx,my) = 1
        call drawcell mx, my, cas(mx,my)
    end if
    unloadbmp "bckgrd1"   'décharge la RAM de l'image...
    #3b "getbmp bckgrd1 0 0 ";WindowWidth;" ";WindowHeight   'mémorise la grille pour servir de background au sprite
 '  #3b "drawbmp bckgrd1 0 0"    'pas utile !
    #3b "background bckgrd1"
    #3b "spritevisible perso";SpriteCourant;" on; drawsprites"
end sub
 
sub DoubleClick handle$, MouseX, MouseY    'double clic sur un point de destination...
    #3b "when leftButtonMove"
    dpx(1) = 0  :dpx(2) = 1 :dpx(3) = 0 :dpx(4) = -1
    dpy(1) = -1 :dpy(2) = 0 :dpy(3) = 1 :dpy(4) = 0    ' incrément en case, de la variables tableau
    icp = 6   'incrément de déplacement en pixels.
    #3b "spritexy? perso";SpriteCourant;" cursX cursY"   'coordonnées actuelles du personnage   <------
    dirX = MouseX - cursX   'comparaison avec celle du clic de souris
    dirY = MouseY - cursY
    if abs(dirX) < abs(dirY) then sens = 1 else sens = 2   '1 = vertical  2 = horizontal
    select case
    case sens = 1
        if dirY > 0 then dir = 3 else dir = 1   'direction à prendre: 1 = HAUT
    case sens = 2                               '                     2 = DROITE
        if dirX > 0 then dir = 2 else dir = 4   '                     3 = BAS
    end select                                  '                     4 = GAUCHE
    for s=1 to 4
        #3b "spritevisible perso";s;" off"
    next
    SpriteCourant = dir
    #3b "spritexy perso";SpriteCourant;" ";cursX;" ";cursY
    #3b "spritevisible perso";SpriteCourant;" on"  'ne montre QUE le sprite concerné par la direction choisie.
    do
        #3b "spritexy? perso";SpriteCourant;" cursX cursY"
        cx = int(cursX/lc)+1             'position du sprite exprimé en n° de case pour la variable tableau
        cy = int(cursY/lc)+1
        if cx+dpx(dir)>0 and cx+dpx(dir)<ncx and cy+dpy(dir)>0 and cy+dpy(dir)<ncy and cas(cx+dpx(dir),cy+dpy(dir)) = 0 and cas(cx+dpx(dir),cy+1+dpy(dir)) = 0 then  'reste dans la map et pas de mur...
            nx = cursX + dpx(dir)*icp
            ny = cursY + dpy(dir)*icp
            #3b "spritexy perso";SpriteCourant;" ";nx;" ";ny      'cheminement du sprite... tranquilou...
            #3b "drawsprites"
            call pause 90
        else
            sortir = 1
        end if
        if (dir = 2 and nx >= MouseX) or (dir = 4 and nx <= MouseX) or (dir = 1 and ny <= MouseY) or (dir = 3 and ny >= MouseY) then sortir = 1
    loop until sortir
    #3b "when leftButtonMove SimpleClick"
end sub
 
sub drawcell xx, yy, v      'montre le contenu d'une case
    #3b "backcolor blue; color blue"
    #3b "place ";(xx-1)*lc+2;" ";(yy-1)*lc+2
    #3b "boxfilled ";xx*lc-1;" ";yy*lc-1
    ' option d'affichage valeur des cases...
    #3b "color yellow"
    #3b "place ";(xx-1)*lc+lc/3;" ";(yy-1)*lc+2*(lc/3)+2;";|";v
end sub
 
sub pause temp
    timer temp, [suit]
    wait
    [suit]
    timer 0
end sub
 
sub Quit handle$
    unloadbmp "JB"
    sprites$ = "perso1d perso2d perso3d perso4d perso1s perso2s perso3s perso4s "+_
               "perso1q perso2q perso3q perso4q perso1z perso2z perso3z perso4z"
    for s = 1 to 16
        unloadbmp word$(sprites$,s)
    next
    close #3b
    END
end sub