' v05 - catapult, weight is fixed on short arm
    ' BTW v04 design performs better (but probably harder to make)
    ' adapted to restart simulation by mouse click
    nomainwin
    UpperLeftX=1
    UpperLeftY=1
    WindowWidth = 1024
    WindowHeight = 440
    open "trebushet" for graphics_nsb_nf as #gr
    #gr "trapclose quit"
    #gr "down"
    #gr "font courier_new"
 
    global xc, yc, scale, shortArm, longArm, aStop, a
 
    xc=200
    yc=200
    scale = 20    'scale pix = 1 meter
    shortArm=1
    longArm=3
 
    #gr "size 1"
    #gr "place ";xc;" ";yc
    #gr "circle ";shortArm*scale
    #gr "place ";xc;" ";yc+shortArm*scale*2
    #gr "\1st mouse click ... release arm"
    #gr "\2nd mouse click ... release projectile"
 
    #gr "when leftButtonDown animate"
    wait
 
sub quit Handle$
    timer 0
    close #Handle$
    end
end sub
 
sub eject Handle$, PosX, PosY
    aStop = 0
end sub
 
sub animate Handle$, PosX, PosY
    #gr "cls"
 
    #gr "size 1"
    #gr "place ";xc;" ";yc
    #gr "circle ";shortArm*scale
    #gr "north;turn 180"  'down
 
    pi=acs(-1)
 
    a=0
    t=0
    a0=0-pi/4            ' start at 225 degrees
    aStop=pi/2 'pi/18    ' end at 100 degrees
    v=0
    g=9.8/6   'm/sec^2 for lunar gravity
    g=9.8     'm/sec^2 for Earth gravity
    L=0       'rope with big weight, down
    dt=.02
    dt2=1000*dt
 
    #gr "when leftButtonDown eject"
 
    while a<aStop
        L=L+dt*v
        v=v+dt*g*cos(a)
        a=L/shortArm+a0
        call draw1
        call pause dt2
        #gr "rule xor"
        call draw1
        #gr "rule over"
    wend
    #gr "when leftButtonDown"
    'last frame
    call draw1
    '#gr "\";a;" ";v;" ";L
    'projectile free motion
    ap=a-pi/2
    x2=0-longArm*cos(a)'*scale+xc
    y2=0-longArm*sin(a)'*scale+yc
    v2=v/shortArm*longArm
    #gr "place ";xc;" ";yc+shortArm*scale*2
    #gr "\leaving velocity ... ";v2;" m/s"
    #gr "\launching angle .... ";180/pi*a;" degrees"
    #gr "\moving angle ....... ";180/pi*(a-a0);" degrees"
    vx=v2*cos(ap)
    vy=v2*sin(ap)
    x=x2
    y=y2
    #gr "size 2"
    while 1
        x=x+dt*vx
        y=y+dt*vy
        vy=vy+dt*g
        #gr "set ";x*scale+xc;" ";y*scale+yc
        call pause dt2
        'so I actually have y inverted...
        if y>0 or x*scale+xc >WindowWidth then exit while
           ' scan
    wend
    #gr "place ";xc;" ";yc+shortArm*scale*2
    #gr "\\\\distance ........... ";x;" m"
 
    #gr "flush"
    #gr "when leftButtonDown animate"
 
end sub
 
sub draw1
    x1=shortArm*cos(a)*scale+xc
    y1=shortArm*sin(a)*scale+yc
    x2=0-longArm*cos(a)*scale+xc
    y2=0-longArm*sin(a)*scale+yc
    #gr "line ";x1;" ";y1;" ";x2;" ";y2
    #gr "set ";x1;" ";y1
    #gr "size 3"
    #gr "circle 2"
    #gr "size 1"
    #gr "place ";xc;" ";yc
    #gr "circle ";shortArm*scale
    #gr "north;turn 180"  'down
end sub
 
sub pause temp   'pause en millisecondes
    timer temp, [temps]
    wait
    [temps]
    timer 0
end sub