nomainwin
 
    WindowWidth = 300
    WindowHeight = 240
    UpperLeftX = (DisplayWidth-WindowWidth) / 3
    UpperLeftY = (DisplayHeight-WindowHeight) / 2
 
    mois$ = "Jan Fév Mar Avr Mai Jun Jui Aou Sep Oct Nov Déc"
    today$ = date$("mm/dd/yyyy")
    j = date$(today$)
    jsem$ = word$("Mar Mer Jeu x Ven Sam x Dim Lun",int((j/7-int(j/7))*10)+1)
    date$ = jsem$+" "+mid$(today$,4,2)+" "+word$(mois$, val(today$))+"   "+left$(time$(),5)'right$(today$,4)

    GLOBAL ajust$, tir$, sequence
    DIM info$(10,10),sequence$(5)
 
    ajust$ = "0uc 0ub 0ua 0 1da 2db 2dc 2dd"
    tir$ = "3 4 5"
    sequence$(1) = "35a 35b 35c"
    sequence$(2) = "37 38 39 40 43 44 45 46 47 48 "          '
    sequence$(3) = "50 51 52 53 54 55 56 57 58 59 60 61 "    ' groupes d'images qui constituent les animations
    sequence$(4) = "65 66 67 68 69 70 71 72 73 74 75 76 "    '
    sequence$(5) = "81 82 83 84 85 86 87 88 89 90 91 92 "    '

    'charge en mémoire les images d'ajustement du tir
    for i = 1 to 8 :loadbmp "img"+word$(ajust$,i), "bmp\"+word$(ajust$,i)+".bmp" :next
    'charge en mémoire les images du tir
    for i = 1 to 3 :loadbmp "img"+word$(tir$,i), "bmp\"+word$(tir$,i)+".bmp" :next
    'charge en mémoire les images d'attente
    for i = 1 to 3 :loadbmp "img"+word$(sequence$(1),i), "bmp\"+word$(sequence$(1),i)+".bmp" :next
    'charge en mémoire les images d'évitement
    for s = 2 to 5
        nbi = int(len(sequence$(s))/3)
        for i = 1 to nbi :loadbmp "img"+word$(sequence$(s),i), "bmp\"+word$(sequence$(s),i)+".bmp" :next
    next
 
    graphicbox #w.g, 10, 10, 241, 137
   ' button #w.b, "Start",[start],UL, 10, 160
   ' button #w.b, "Arm",[arm],UL, 60, 160
    button #w.b, "Tir",Tir,UL, 100, 160
    button #w.b1, "+3",ajusteTir,UL, 260, 10
    button #w.b2, "+2",ajusteTir,UL, 260, 36
    button #w.b3, "+1",ajusteTir,UL, 260, 62
    button #w.b4, "00",ajusteTir,UL, 260, 88
    button #w.b5, "-1",ajusteTir,UL, 260, 114
    button #w.b6, "-2",ajusteTir,UL, 260, 140
    button #w.b7, "-3",ajusteTir,UL, 260, 166
    open "In Japan..."+space$(10)+date$ for window_nf as #w
    #w "trapclose quit"
    #w.g "down"
 
    call attente
 
    WAIT
 
    sub attente
        sequence = 1
        DO
            call anime sequence
            call pause 250
        LOOP UNTIL sequence <> 1   'sequence est modifié dès qu'on presse un bouton...
    end sub
 
    sub Tir handle$
        if sequence = 1 then sequence = 4  'si aucun bouton d'ajustement n'a été pressé...
        for i = 1 to 4
            #w.g "drawbmp img";word$("0 3 4 5",i);" 0 0"  'séquence de tir.
            call pause 200
        next
        call anime sequence    'lancement de la sequence d'évitement
        call pause 1000
        call attente      'retour à la sequence d'attente
    end sub
 
    sub ajusteTir handle$  ' réglage de la mire ;)
      'affiche une image et sélectionne une séquence en fonction du bouton pressé.
        image = val(right$(handle$,1))
        #w.g "drawbmp img";word$(ajust$,image);" 0 0"
        select case image
        case 1,2
            sequence = 2
        case 3
            sequence = 3
        case 4,5
            sequence = 4
        case 6,7
            sequence = 5
        end select
    end sub
 
    sub anime seq       ' routine générique d'animation
        nbi = int(len(sequence$(seq))/3)
        for i = 1 to nbi
            #w.g "drawbmp img";word$(sequence$(seq),i);" 0 0"
            call pause 100
        next
    end sub
 
    sub pause temp   'pause en millisecondes
        timer temp, [temps]
        wait
        [temps]
        timer 0
    end sub
 
    sub quit handle$
        for i = 1 to 8 :unloadbmp "img"+word$(ajust$,i) :next
    'décharge les images du tir
        for i = 1 to 3 :unloadbmp "img"+word$(tir$,i) :next
    'décharge les images d'attente
        for i = 1 to 3 :unloadbmp "img"+word$(sequence$(1),i) :next
    'décharge les images d'évitement
        for s = 2 to 5
            nbi = int(len(sequence$(s))/3)
            for i = 1 to nbi :unloadbmp "img"+word$(sequence$(s),i) :next
        next
        close #handle$
        END
    end sub